onClipEvent (load) {
//影片加载后对需要用到的变量进行初始化,影片加载一次初始化一次.
 stop ();//group影片停止在第一帧.
 check = false;
 //判定鼠标左键是否按下用,初始化为假,即鼠标没有按下.
 _root.all_perss_check = true;
 //用以记录是否有按钮被按下.初始化为真.即没有按钮被按下.
 Label_x = label._x;//记录动态文本label的坐标.
 Label_y = label._y;
}
onClipEvent (mouseDown) {
//鼠标按下事件.每点按下一次执行一次
 if (hitTest(_root._xmouse, _root._ymouse, false)) {
  //判定鼠标是否跟按钮重叠,
  //在flash帮助(按F1)里具体说明,
  //注重,鼠标必须也按钮重叠时按下才能执行下面的语句.
  check = true;//鼠标已经按下.
  _root.all_perss_check = false;//已经有按钮被按下了.所以为假.
 }
}
onClipEvent (enterFrame) {
//每秒都执行的事件(执行次数为帧频数)
 if(_parent.loic == "true"){
 //判定loic(用以判定按钮是否被禁用,默认为"true"即没有被禁用)变量的值.
 //假如值等于字符串true则执行下面语句,注重,在flash MX中不需要带双引号,否则不能执行.
  if(hitTest(_root._xmouse,_root._ymouse,false) && _root.all_perss_check){
  //判定,假如鼠标与按钮重叠,并且没有别的按钮被按下
  LabelColor = new Color(label);
  //为动态文本框构造一个颜色容器
  LabelColor.setRGB(0x0000FF);
  //设置文字变色.这一段的实现效果是,鼠标划过按钮.文字变色.
 }else{//否则.即鼠标没有与按钮重叠
  LabelColor = new Color(label);
  LabelColor.setRGB(0x000000);//将文字颜色还原为黑色.
 }
 if (hitTest(_root._xmouse, _root._ymouse, false) && check){
 //鼠标与按钮重叠,并且在按钮上按下了左键.
  label._x = Label_x + 1;//文字坐标移动1个象素.让文字有被按下的感觉
  label._y = Label_y + 1;
  nextFrame ();//group MC跳到下一帧.
 } else {//鼠标没有与按钮重叠,或者没有在按钮上按下左键.
  label._x = Label_x;//文字坐标还原.
  label._y = Label_y;
  shadowcolor = new Color(shadow);
  shadowcolor.setRGB(0xECE9D8);
  //将实例名为shadow的动态文本框的颜色设置为按钮色(即第二帧所填的颜色)
  prevFrame ();//group MC跳到上一帧
 }
}else{//按钮被禁用了,这段语句用于创建一个阴影效果
 labelcolor = new Color(label);
 labelcolor.setRGB(0xACA899);
 shadow._x = Label_x + 1;
 shadow._y = Label_y + 1;
 shadowcolor = new Color(shadow);
 shadowcolor.setRGB(0xFFFFFF);
 }
}
onClipEvent (mouseUp) {//鼠标左键松开(按下->松开)时执行
 check = false;//鼠标没有被按下.
 _root.all_perss_check = true;//没有按钮被按下.
}

　　onClipEvent (load) {
  Onperss = false;
}
onClipEvent (mouseDown) {
  if (hitTest(_root._xmouse, _root._ymouse, true)) {
  Onperss = true;
 }
}
onClipEvent (mouseUp) {
  if (hitTest(_root._xmouse, _root._ymouse, true) && Onperss && 
  loic == "true") {//同样,假如是在flash MX中,不要带双引号.
  //要执行的代码就写在这里.
  //不过要注重.因为是写在MC上面,所以一定记要带上_root(或者_parent)来指定对象
  getURL("http://www.webjx.com");
  } else {
  Onperss = false;
  }
}

　　onClipEvent (load) {
  souCheck = false;
}
onClipEvent (mouseMove) {
 if (hitTest(_root._xmouse,_root._ymouse,true)) {
 if (!souCheck && _root.all_perss_check) {
  mysound = new Sound();
  mysound.attachSound("buttonsound" + [Math.floor(Math.random() * 10)]);
  mysound.start(0,1);
  souCheck = true;
 }
 }else{
 souCheck = false;
 }
}

　　mysound.attachSound("buttonsound" + [Math.floor(Math.random () * 10)]);